***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 15, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5226B A K 
.param
+vc0 = 7.296e-10 	 vc1 = 2.883e-7 	 vc2 = 1.100e0		 vc3 = 2.921e-6		 vc4 = 7.790e0
+tc1 = 9.551e-3		 tc2 = 8.821e-3		 tc3 = 4.391e-3		 tc4 = 1.011e-3	 
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1.739e-14	   n = 1.123		  rs = 5.086e-1
+ibv = 3e-4		 nbv = 1.0		  bv = 3.3
+ikf = 7.875e-1
***** capacitance parameter *****
+cjo = 2.024e-10	   m = 3.191e-1		  vj = 7.322e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.08		 xti = 3
+trs1 = 7.325e-4	trs2 = 7.865e-6
+tbv1 = -1.0487e-3	tbv2 = 7.456e-8		tikf = 4e-2
.ends MMSZ5226B
*$
